[How-To] WinRE-Ramdisk-Eintrag erstellen ֍ Startmenü aufbohren

Tools, Installation, Optimierung, Problemlösung rund ums Thema Windows 10
Antworten
Benutzeravatar
Nemo
Support
Beiträge: 1277
Registriert: Di 12. Jul 2016, 12:28
Wohnort: Bad Soden am Taunus
    Windows 10 Firefox
Hat sich bedankt: 151 Mal
Danksagung erhalten: 132 Mal
Status: Online

[How-To] WinRE-Ramdisk-Eintrag erstellen ֍ Startmenü aufbohren

#1

Beitrag von Nemo » Mi 17. Aug 2016, 11:53

WinRE-Ramdisk-Eintrag erstellen
֍
Startmenü aufbohren
Ernstfall:
PC/Laptop startet nicht mehr und man hat kein Notfallmedium erstellt: Was nun?
Hier werden der Beitrag und der danach entstandene Thread von Bezelbube aus Win-Lite.de zusammengefasst dokumentiert, bevor der Betreiber Finn Hillebrandt das Forum aufgibt.
Die Recoverysequenz der OEMs ist ja schön und gut, aber man fällt wieder in die Steinzeit zurück und hat wieder die ganze Bloat- und Crapware der OEMs am Hals.
Es ist ja schon ein absoluter Glückfall, wenn man ins Bootmenü von Windows kommt, falls es überhaupt gelingt.
Mit dem Erstellen des Ramdiskeintrags zur Betriebssystemauswahl hat man schon ein Notfallmedium an Bord. Mit ein paar Mausklicks lässt sich dann das selbst erstellte Windowsimagebackup wiederherstellen und man befindet sich auch schon im Erweiterten Bootmenü von Windows.
Integriert man noch MSDaRT in die WinRE.wim (siehe HIER), hat man noch entschieden bessere Karten, kleinere oder auch größere Problemchen zu beheben.

Die folgende Vorgehensweise ist nur für User zu empfehlen, die eine saubere Neuinstallation ("clean!") vorgenommen haben und sich zutrauen, Änderungen an der Systempartition vorzunehmen!
Bei denjenigen, die bislang nur das Upgrade auf Win 10 vorgenommen haben, liegt ein richtiges Partitions-Wirrwar vor und es ist dann nicht so einfach, den richtigen BCDEDIT-Eintrag herauszufischen.

WindowsImageBackup

Man kann so viele WindowsImageBackups erstellen, bis das Ziellaufwerk platzt. Darum sollte man glegentlich einzelne WindowsImageBackups löschen:

Code: Alles auswählen

wbadmin get versions -backupTarget:D: (listet die WindowsImageBackups auf)
wbadmin delete backup -version:03/31/2014-12:33 (löscht nur das Backup von diesen Datum)
wbadmin delete catalog -quiet (dann kann man den ganzen Ordner WindowsImageBackup löschen)
Autor: Bezelbube(AT)Win-Lite.de

WinRE-Ramdisk-Eintrag erstellen

Funktion:
Eine Ramdisk ist ein virtueller und temporärer Datenträger im Arbeitsspeicher (RAM) eines Computers.
Beim Anlegen wird ein gewisser Anteil des Arbeitsspeichers statisch oder auch dynamisch für die RAM-Disk reserviert.

Vorbereitung/Backup erstellen:
Eingabeaufforderung als Admin öffnen:

Code: Alles auswählen

wbadmin start backup -backuptarget:D: -include:C: -allcritical -quiet
Die boot.sdi nach C:\boot kopieren; zu finden im Ordner "boot" auf der Windows-DVD.
Die WinRE.wim nach C:\boot kopieren; zu finden im Ordner .\Windows\System32\Recovery einer z. B. mit 7.zip entpackten "Install.wim"
Oder, wenn man sich mit den Befehl Recoverydrive ein Notfallmedium erstellt hat, aus dem Ordner "sources" die "boot.wim" nach C:\boot kopieren und in "WinRE.wim" umbenennen.

Globally Unique Identifier (GUID)
  • Die vordefinierte GUID für einen Ramdiskeintrag, im Rest dieses Verfahrens als {GUID1} bezeichnet, lautet:
    {AE5534E0-A924-466C-B836-758539A3EE3A}
  • {GUID2} wird nach Ausführen vom 4. Befehl ausgegeben und die Bezeichnung in den " " für den Bootmenüeintrag beim 4. Befehl ist frei wählbar.
Diese Befehle ausführen, um WinRE dem BCD hinzuzufügen:

Code: Alles auswählen

 1.  Bcdedit –create {GUID1}
 2.  Bcdedit –set {GUID1} ramdisksdidevice partition=C:
 3.  Bcdedit -set {GUID1} ramdisksdipath \boot\boot.sdi
 4.  Bcdedit /create /d “Windows Recovery Environment” /application osloader
Der letzte Befehl gibt eine Kennung GUID für den neu erstellten Eintrag aus. Dieser neue Eintrag wird im Rest dieses Verfahrens als {GUID2} bezeichnet. Statt {GUID2} die Kennung des neu erstellten Eintrags einsetzen.

Code: Alles auswählen

 5.  Bcdedit –set {GUID2} device ramdisk=[c:]\boot\WinRE.wim,{GUID1}
 6.  Bcdedit –set {GUID2} osdevice ramdisk=[c:]\boot\WinRE.wim,{GUID1}
 7.  Bcdedit –set {GUID2} systemroot \Windows
 8.  Bcdedit –set {GUID2} detecthal Yes
 9.  Bcdedit –set {GUID2} winpe Yes
10.  Bcdedit -displayorder {GUID2} -addlast
11.  Bcdedit –set {bootmgr} timeout 3
PC neu starten und den WinRE-Eintrag auswählen,
dann auf Problembehandlung -->Erweiterte Optionen-->Systemimagewiederherstellung--> das Betriebssystem wählen und schon ist das Windowsimagebackup mit Datum und Uhrzeit, welches zu Anfang dieses Posts erstellt wurde, zu sehen.
Betriebsystem wieder starten und den Befehl "wbadmin delete catalog -quiet" ausführen und den Windowsimagebackupordner löschen.
Neues Windowsimagebackup anlegen: Siehe Postanfang.
Jetzt hat man seine eigene aktuelle Recoverysequenz mit dem Ramdiskeintrag im Bootmenü.

Möchte man ein anderes Bootimage als "winre" dem Bootmenü hinzufügen,
- beim 4. Befehl die Bezeichnung des Bootmenüeintrages anpassen und
- beim 5. + 6. Befehl den Namen der *.wim ändern.

Will man noch einen weiteren Ramdiskeintrag dem Bootmenü hinzufügen,
die Befehle 4 bis 10 nur noch einmal ausführen, nachdem man, wie eben angefügt, die Befehle 4, 5 und 6 angepasst hat.

Beispiel:

Code: Alles auswählen

Bcdedit –create {AE5534E0-A924-466C-B836-758539A3EE3A}
Bcdedit –set {AE5534E0-A924-466C-B836-758539A3EE3A} ramdisksdidevice partition=C:
Bcdedit -set {AE5534E0-A924-466C-B836-758539A3EE3A} ramdisksdipath \boot\boot.sdi
Bcdedit /create /d “Windows Recovery Environment” /application osloader
als neue GUID wurde {0e6d1ecc-b6a5-11e5-8b1a-080027ae6fc9} ausgegeben; diese wird anstatt der {GUID2} eingesetzt.
  1. Bcdedit –set {0e6d1ecc-b6a5-11e5-8b1a-080027ae6fc9} device ramdisk=[c:]\boot\WinRE.wim,{AE5534E0-A924-466C-B836-758539A3EE3A}
  2. Bcdedit –set {0e6d1ecc-b6a5-11e5-8b1a-080027ae6fc9} osdevice ramdisk=[c:]\boot\WinRE.wim,{AE5534E0-A924-466C-B836-758539A3EE3A}
  3. Bcdedit –set {0e6d1ecc-b6a5-11e5-8b1a-080027ae6fc9} systemroot \Windows
  4. Bcdedit –set {0e6d1ecc-b6a5-11e5-8b1a-080027ae6fc9} detecthal Yes
  5. Bcdedit –set {0e6d1ecc-b6a5-11e5-8b1a-080027ae6fc9} winpe Yes
  6. Bcdedit -displayorder {0e6d1ecc-b6a5-11e5-8b1a-080027ae6fc9} -addlast
  7. Bcdedit –set {bootmgr} timeout 3
Weiteres Bootimage hinzufügen

Code: Alles auswählen

Bcdedit /create /d “O & O DiskImage” /application osloader
als neue GUID wurde {0e6d1ecd-b6a5-11e5-8b1a-080027ae6fc9} ausgegeben
  1. Bcdedit –set {0e6d1ecd-b6a5-11e5-8b1a-080027ae6fc9} device ramdisk=[c:]\boot\oodi.wim,{AE5534E0-A924-466C-B836-758539A3EE3A}
  2. Bcdedit –set {0e6d1ecd-b6a5-11e5-8b1a-080027ae6fc9} osdevice ramdisk=[c:]\boot\oodi.wim,{AE5534E0-A924-466C-B836-758539A3EE3A}
  3. Bcdedit –set {0e6d1ecd-b6a5-11e5-8b1a-080027ae6fc9} systemroot \Windows
  4. Bcdedit –set {0e6d1ecd-b6a5-11e5-8b1a-080027ae6fc9} detecthal Yes
  5. Bcdedit –set {0e6d1ecd-b6a5-11e5-8b1a-080027ae6fc9} winpe Yes
  6. Bcdedit -displayorder {0e6d1ecd-b6a5-11e5-8b1a-080027ae6fc9} -addlast
Bild Bild


Die folgende Vorgehensweise ist nur für User zu empfehlen,die eine saubere Neuinstallation ("clean!") vorgenommen haben und sich zutrauen, Änderungen an der Systempartition vorzunehmen!!!
Bei denjenigen, die bislang nur das Upgrade auf Win 10 vorgenommen haben, liegt ein richtiges Partitions-Wirrwar vor und es ist dann nicht so einfach, den richtigen BCDEDIT-Eintrag herauszufischen.


Gibt man in der Eingabeaufforderung bcdedit ein, werden einem nur die Einträge des Bootmanagers und des Betriebssystems (Windows-Start-Ladeprogramm) angezeigt.
Gibt man bcdedit -enum all ein, wird der WinRE Ramdiskeintrag der Systempartition mit aufgeführt:
"ramdisk=[\Device\HarddiskVolume1]\..." = Systempartition.
Von diesen Eintrag kopiert man sich nur die GUID, die neben Bezeichner angeführt wird (im Bild gelb makiert) und führt dann insgesamt nur
drei Befehle aus:
  1. bcdedit -enum all
  2. bcdedit -displayorder {ca497cd0-c15f-11e5-9ee6-0800278db2d6} -addlast
  3. bcdedit -timeout 3
Gibt man anschließend "bcdedit" ein, wird der WinRE Ramdiskeintrag mit angeführt.
Anschließend habe ich meinen PC mit MSDaRT gebootet und habe die winre.wim auf der Systempartition mit meiner winre.wim incl. MSDaRT-Copy-Folder ausgetauscht.

Bild Bild

Autor: Bezelbube(AT)Win-Lite.de

WinRE-Eintrag lt c't

Basierend auf "Was Windows 7 für den Notfall mitliefert --- Eingebaute Selbstheilung", einem Artikel aus einer c't des Jahres 2011, habe ich mir danach eine unverändert auch unter Windows 10 funktionierende Prozedur gebaut, die ebenso, wie im Eingangsbeitrag von @Bezelbube beschrieben, einen Menüeintrag für die Windows-Wiederherstellungsumgebung (Windows Recovery Environment / WinRE) erstellt:

Code: Alles auswählen

@ECHO OFF
:: WINREMENU.CMD
TITLE WinRE für Bootmenü
IF NOT "%1"==""  GOTO :Einricht
bcdedit >%TEMP%\WINRE.TXT /enum all
START NOTEPAD %TEMP%\WINRE.TXT
COLOR 4F
ECHO.
ECHO WinRE für Bootmenü erstellen
ECHO Quelle: c't 2011/13 S.139
ECHO Kurzanleitung:
ECHO - Auszuführen als Administrator!
ECHO - Auslesen der GUID von "recoverysequence" aus Notepad-Anzeige
ECHO - Kopieren in Zwischenablage
ECHO - Erneuter Aufruf dieser Prozedur MIT der gespeicherten GUID
PAUSE
COLOR 2F
GOTO :Ende

:Einricht
COLOR 2F
bcdedit /displayorder %1 /addlast
bcdedit /set %1 description "Windows Recovery Environment"
bcdedit /enum
ECHO.
PING >NUL localhost -n 5
DEL %TEMP%\WINRE.TXT

:Ende
Sie benutzt im Gegensatz zu der bereits vorgestellten Lösung die hinterlegte WinRE.wim in der Systempartition
([Device\Harddiskvolume1]\Recovery\WindowsRE\winre.wim).

Der Eintrag wird in zwei Schritten erstellt:
  • Erster Aufruf der Prozedur ohne weitere Argumente. Es erscheint eine Anzeige in einem Notepad-Fenster. Aus dem ist die angezeigte GUID (z. B. {9dd38268-c781-11e5-a158-000c29fa05b2}) in die Zwischenablage zu übernehmen.
  • Zweiter Aufruf der Prozedur mit der zwischengespeicherten {GUID} als Argument. Beispiel:

    Code: Alles auswählen

    winremenu.cmd {9dd38268-c781-11e5-a158-000c29fa05b2}
Das war's auch schon - es sei denn, man will auch noch MS DaRT einbinden.

Hier kommnt eine spezielle boot.wim ins Spiel, die man sich nach dieser Anleitung gebaut hat. Sie ersetzt unter Namensänderung die WinRE.wim in der Systempartition. Für mich habe ich das so gelöst, dass ich
  • mit Hilfe des Festplattenmangers der Systempartition den NTFS-Ordner "D:\!#MOUNT\!#HD01" zuweise und anschließend
  • mit einem gescheiten Dateimanager (z. B. Total Commander) die vorhandene "D:\!#MOUNT\!#HD01\\Recovery\WindowsRE\winre.wim" überschreibe.
    Achtung: WinRE.wim ist als versteckte Systemdatei markiert.
    Anmerkung: In einer VM habe ich die Systempartition von 500 auf 1.001 MiB aufgebohrt; so konnte ich vorher zur Sicherung die alte WinRE.wim in *.ORG umbenennen und habe immer noch Platz für zukünftige weitere Tests.
Ergänzung 2018-02-17:
===================

Wer von seinem PC-Hersteller keine Wiederherstellungsumgebung mitgeliefert bekommen oder seine selbst zerschossen hat, vertiefe sich in den Artikel "Windows RE prüfen und reparieren --- Hilfe für den Helfer" einer c't von 2018.

Darin wird beschrieben, wie man wenigen Befehlen mit Hilfe einer WinRE.WIM, die man aus dem Verzeichnis %windir%\System32\Recovery (notfalls eines anderen Rechners gleicher Version und Architektur) gefischt hat, wieder an eine funktionsfähige Wiederherstellungsumgebung kommt.


Autor: Nemo(AT)Win-Lite.de

WinRE-Booteintrag mit OODI

WinRE-Booteintrag mit O&O DiskImage erstellen
Hier habe ich die Beschreibung von Bezelbube ebenfalls in eine Prozedur OODIMENU.CMD umgesetzt, damit ich das ganze auch ohne Waschzettel wiederholen kann.

Code: Alles auswählen

:: OODIMENU.CMD
::Stand 2017-12-17
@ECHO OFF
COLOR 4F

SET "PE=OODI"
SET "PEver=12"
SET "WIMtxt=O+O DiskImage %PEver%"
SET "UEB====== Einstellen O+O Disk Image v%PEver% in Windows-Bootmenü ====="
:: GUID2 für OODI ist im zweiten Aufruf mit zu übergeben

:: Es folgt Definition GUID1 für RAMdisk
SET "GUID1={AE5534E0-A924-466C-B836-758539A3EE3A}" 

TITLE %UEB%
SET "V3264=32"
SET "X6486=86"
SET "SYS3264=system32"
IF NOT "%ProgramFiles(x86)%"==""   SET "V3264=64" && SET "X6486=64" && SET "SYS3264=SysWOW64"

SET "WinRE-HL=C:\!#MOUNT\!#HD04"
SET "WinRE=%WinRE-HL%\Recovery\WindowsRE"
SET "WIM=boot%PE%%PEver%-x%X6486%.WIM"
SET "FQDNWIM=%~dp0!WIM\%WIM%"

SET "RgEd=%SystemRoot%\Regedit.exe"

IF NOT EXIST C:\Boot\NUL  MD C:\Boot

:SDIinC
IF EXIST C:\Boot\boot.sdi   GOTO :WIMinC
ATTRIB -S -H %WinRE%\boot.sdi  
IF NOT EXIST %WinRE%\boot.sdi     GOTO :FehlSDI  
::ECHO boot.sdi wird nach C:\Boot kopiert
COPY /Y      %WinRE%\boot.sdi     C:\Boot\*.*   >NUL
ATTRIB +S +H %WinRE%\boot.sdi  
::GOTO :WIMinC  

:WIMinC
IF EXIST C:\Boot\%WIM%   GOTO :MKmenu
IF NOT EXIST %FQDNWIM%   GOTO :FehlWIM
::ECHO %WIM% wird nach C:\Boot kopiert
COPY /Y  %FQDNWIM%       C:\Boot\*.*   >NUL
::GOTO :MKmenu  

:MKmenu
::ECHO Boot.sdi und %WIM% nunmehr nach C:\Boot kopiert
IF NOT "%1"==""  GOTO :2ndRun

ECHO.
ECHO %UEB%
ECHO.
ECHO Derzeitige Position der Wiederherstellungsumgebung
ECHO.
REAGENTC.EXE /info
ECHO.
ECHO Wenn die Wiederherstellungsumgebung WinRE.wim derzeit nicht unter 
ECHO %WinRE% zu finden ist, dann
ECHO - Abbruch dieser Prozedur
ECHO - Inhalt der Variable WinRE-HL in Prozedur anpassen 
ECHO - Prozedur erneut aufrufen
ECHO.
PAUSE

ECHO.
ECHO Vorausetzungen:
ECHO - WIM für %PE% ist bereitzustellen als 
ECHO   %FQDNWIM%;
ECHO   sonst Variable FQDNWIM ändern!
ECHO - Inhalt der Wiedeherstellungsumgebung mit Pfad zu WinRE.wim ist 
ECHO   bereitzustellen unter %WinRE%;
ECHO   sonst Variable WinRE ändern!
ECHO - Andernfalls sind boot.sdi und %WIM% händisch in C:\Boot bereitzustellen
ECHO.  
ECHO Kurzanleitung:
ECHO - Auszuführen als Administrator!
ECHO - Auslesen des Eintrags in spitzen Klammern {GUID} aus Notepad-Anzeige
ECHO - Kopieren mit den spitzen Klammern in die Zwischenablage
ECHO.
ECHO - Erneuter Aufruf dieser Prozedur MIT der zwischengespeicherten GUID
ECHO.
ECHO Quelle: "https://www.win-unattended.de/viewtopic.php?p=259#p259"
ECHO Danksagung an Bezelbube@win-unattended.de
ECHO.

:1stRun
ECHO Eintrag für "%WIMtxt%" wird für Bootmenü erstellt
bcdedit >%TEMP%\WINPE.TXT /create /d "%WIMtxt%" /application osloader
START NOTEPAD %TEMP%\WINPE.TXT
COLOR 4F
ECHO.
ECHO ####  Erneuter Aufruf dieser Prozedur MIT der zwischengespeicherten GUID  ####
ECHO.
PAUSE
GOTO Ende

:2ndRun
Bcdedit -create %GUID1%
ECHO.
ECHO #####   Ein evtl. vorangegangener Fehler kann ignoriert werden,   #####
ECHO #####   wenn ein RAMdiskeintrag bereits früher erstellt wurde     #####
ECHO.
Bcdedit -set    %GUID1% ramdisksdidevice partition=C:
Bcdedit -set    %GUID1% ramdisksdipath   \boot\boot.sdi
COLOR 2F
ECHO %1 als {GUID2} übergeben
Bcdedit -set          %1   device ramdisk=[c:]\boot\%WIM%,%GUID1%
Bcdedit -set          %1 osdevice ramdisk=[c:]\boot\%WIM%,%GUID1%
Bcdedit -set          %1 systemroot \Windows
Bcdedit -set          %1 detecthal Yes
Bcdedit -set          %1 winpe Yes
Bcdedit -displayorder %1 -addlast
Bcdedit -set   {bootmgr} timeout 7
ECHO.
PAUSE
COLOR 1F
DEL %TEMP%\WINPE.TXT 
IF EXIST %SystemDrive%\P\EASYBCD\EasyBCD.exe  START /MAX %SystemDrive%\P\EASYBCD\EasyBCD.exe
GOTO Ende

:FehlSDI
COLOR 4F
ECHO.
ECHO Boot.SDI nicht gefunden!  Abhilfe:
ECHO.
ECHO - Boot.sdi ist von Hand nach %BootPE% zu kopieren oder bessser
ECHO - Systempartition per Festplatten-Manager bereitstellen in %WinRE-HL%
ECHO.
ECHO Abbruch!
PAUSE
GOTO :Ende

:FehlWIM
COLOR 4F
ECHO.
ECHO %WIM% nicht gefunden!  Abhilfe:
ECHO.
ECHO - %WIM% ist von Hand nach %StartPart%\%BootPE% zu kopieren
ECHO.
ECHO Abbruch!
PAUSE
GOTO :Ende
:Ende
Erläuterungen:
  • Es werden bei mir per Hardlink bereitgestellt
    • C:\!#MOUNT\!#HD01 <--- Systempartition
    • C:\!#MOUNT\!#HD04 <--- Wiederherstellungspartition
  • Boot.sdi wird aus aus der Wiederherstellungspartition nach C:\Boot kopiert;
    in der urspünglichen Version wurde sie der Systempartition entnommen.
  • BootOODI12-x64.wim oder BootOODI12-x86.wim wird entsprechend der vorgefundenen Architektur nach C:\Boot kopiert
    Es wird die nachfolgende Struktur vorausgesetzt, andernfalls sind Variableninhalte am Anfang zu ändern:

    Code: Alles auswählen

    <beliebiger Ordner>\.
    |   OODIMENU.CMD
    |       
    \---!WIM
            bootOODI12-x64.wim
            bootOODI12-x86.wim
    • Meine Idee, C:\!#MOUNT\!#HD04\Boot an Stelle von C:\Boot für die Ablage zusätzlicher Boot-WIMs zu nutzen, ist daran gescheitert, dass der Wiederherstellungspartion bei mir kein Laufwerksbuchstabe zugeordnet wird und dass das beschriebene Procedere nicht mit den Hardlinks zurechtkommt.


    Autor: Nemo(AT)Win-Lite.de ---> Nemo(AT)Win-Unattended.de

    Ergänzung / Anhang

    BCD-Einträge der vorstehend beschriebenen Lösung in einer Win10x86-VM (hier in der Darstellung unter EasyBCD):

    Bild

    Code: Alles auswählen

    Windows Boot Manager
    --------------------
    identifier              {9dea862c-5cdd-4e70-acc1-f32b344d4795}
    device                  partition=\Device\HarddiskVolume1
    description             Windows Boot Manager
    locale                  de-DE
    inherit                 {7ea2e1ac-2e61-4728-aaa3-896d9d0a9f0e}
    default                 {9dd38267-c781-11e5-a158-000c29fa05b2}
    resumeobject            {9dd38266-c781-11e5-a158-000c29fa05b2}
    displayorder            {9dd38267-c781-11e5-a158-000c29fa05b2}
                            {9dd38268-c781-11e5-a158-000c29fa05b2}
                            {43cad348-c78c-11e5-8e35-000c29fa05b2}
    toolsdisplayorder       {b2721d73-1db4-4c62-bf78-c548a880142d}
    timeout                 7
    
    Windows Boot Loader
    -------------------
    identifier              {9dd38267-c781-11e5-a158-000c29fa05b2}
    device                  partition=C:
    path                    \Windows\system32\winload.exe
    description             Windows 10
    locale                  de-DE
    inherit                 {6efb52bf-1766-41db-a6b3-0ee5eff72bd7}
    recoverysequence        {9dd38268-c781-11e5-a158-000c29fa05b2}
    recoveryenabled         Yes
    allowedinmemorysettings 0x15000075
    osdevice                partition=C:
    systemroot              \Windows
    resumeobject            {9dd38266-c781-11e5-a158-000c29fa05b2}
    nx                      OptIn
    bootmenupolicy          Standard
    
    Windows Boot Loader
    -------------------
    identifier              {9dd38268-c781-11e5-a158-000c29fa05b2}
    device                  ramdisk=[\Device\HarddiskVolume1]\Recovery\WindowsRE\Winre.wim,{9dd38269-c781-11e5-a158-000c29fa05b2}
    path                    \windows\system32\winload.exe
    description             Windows Recovery Environment
    locale                  de-DE
    inherit                 {6efb52bf-1766-41db-a6b3-0ee5eff72bd7}
    displaymessage          Recovery
    osdevice                ramdisk=[\Device\HarddiskVolume1]\Recovery\WindowsRE\Winre.wim,{9dd38269-c781-11e5-a158-000c29fa05b2}
    systemroot              \windows
    nx                      OptIn
    bootmenupolicy          Standard
    winpe                   Yes
    custom:46000010         Yes
    
    Windows Boot Loader
    -------------------
    identifier              {43cad348-c78c-11e5-8e35-000c29fa05b2}
    device                  ramdisk=[C:]\boot\bootOODI10-x86.WIM,{ae5534e0-a924-466c-b836-758539a3ee3a}
    description             O+O DiskImage 10
    osdevice                ramdisk=[C:]\boot\bootOODI10-x86.WIM,{ae5534e0-a924-466c-b836-758539a3ee3a}
    systemroot              \Windows
    bootmenupolicy          Standard
    detecthal               Yes
    winpe                   Yes
    


    Autor: Nemo(AT)Win-Lite.de
    Gruß, Nemo

    PS:
    Hier wurden der Beitrag und der danach entstandene Thread von Bezelbube aus dem Forum Win-Lite.de zusammengefasst dokumentiert, bevor der Betreiber Finn Hillebrandt das Forum Ende September 2016 aufgibt.

    PS2:
    Bezelbube hat sich mir gegenüber in einer PN ausdrücklich damit einverstanden erklärt, dass ich Posts von ihm in dieses Forum übernehme.
    Zuletzt geändert von Nemo am Sa 17. Feb 2018, 19:36, insgesamt 7-mal geändert.

    Benutzeravatar
    Nemo
    Support
    Beiträge: 1277
    Registriert: Di 12. Jul 2016, 12:28
    Wohnort: Bad Soden am Taunus
      Windows 10 Firefox
    Hat sich bedankt: 151 Mal
    Danksagung erhalten: 132 Mal
    Status: Online

    Windows-Startmenü um O&O Disk Image Pro erweitern

    #2

    Beitrag von Nemo » Di 19. Dez 2017, 17:38

    Windows-Startmenü erweitern um einen Aufruf von OODI 12

    Meinen Eingangsbeitrag habe ich ergänzt um die Beschreibung zum Einbinden der derzeitig aktuellen Version 12 des Disk Image Pro der Fa. O&O Software in ein Startmenü von Windows 10.

    Da ich zu der Erkenntnis gekommen bin, die Wiederherstellungs-Partition ans Ende der ersten Platte zu verlegen, war meine Idee, analog zur Beschreibung der zweiten Variante in Abschnitt 4 eines anderen Beitrags zusätzliche Boot.WIMs in eine entsprechend groß dimensionierte Partitition ohne Laufwerkbuchstaben zu verlegen, damit trotz Fehlern im Dateisystem von C: WinRE.WIM, BootOODI12-x??.WIM und auch andere im Zugriff für Reparatur- und Datensicherungs-Arbeiten bleiben.
    Wenn ich aber mit WIMs wie C:\!#MOUNT\!#HD04\Boot\BootOODI12-x64.WIM
    --- physisch also unter \\?\GLOBALROOT\device\harddisk0\partition4\Boot\BootOODI12-x64.WIM ---
    an Stelle von C:\BootBootOODI12-x64.WIM starten wollte, hat Windows nicht mitgespielt.

    So blieb es bei C:\Boot für das Hinterlegen zusätzlicher Boot-WIMs.

    Anregungen, um vorstehende Absichten erfolgreich umzusetzen, nehme ich gerne entgegen.

    Gruß, Nemo

    Antworten

    Social Media